12 Aralık 2016 Pazartesi

AX 2012 - X++ kodu ile Questionnaires çalıştırma ve Answer tablosundan answer Id alma

Questionnaires kullanımı ve çalıştırma hakkında bir çok sayfa var web'de. Bu yüzden Questionnaires nedir, nasıl kullanılır konusunda bir şey anlatmayacağım.

KMCollection - Questionnaire kayıtları tablosu. kmCollectionId anahtar alan.

KMVirtualNetworkAnswerTable - Cevaplar tablosu.  kmVirtualNetworkAnswerTableId anahtar alan. evaluation alanında failed/passed veya boş olarak sonuç saklı.
KMVirtualNetworkAnswerLine - Cevap satırları tablosu.

Kod ile Questionnaire formu çalıştırma:


  
KMQuestionnaireRun       o = new CrsKMQuestionnaireRun();
 

o.set(KMQuestionnaireRunMode::All,myKMCollectionId, DirPersonUser::find(curUserId()).party());
o.run();
Kod ile Answer formu çalıştırma:

KMVirtualNetworkAnswerTable answerTable;
Args                        args = new Args();
RecId                       recId = DirPersonUser::find(curUserId()).party();
 

select firstOnly answerTable
        where answerTable.kmVirtualNetworkAnswerTableId == this.AnswerId;

args.record(answerTable);args.caller(o);
    new MenuFunction(menuItemDisplayStr(KMKnowledgeCollectorUserResults), MenuItemType::Display).run(args);


Questionnaire Idlerini sakladığım kendi formumdan ve tablomdan kod ile Questionnaire formu çalıştırıp oluşan KMVirtualNetworkAnswerTable kaydının ID'sini almak için KMQuestionnaireRun_Win32 sınıfından yeni bir sınıf türettim:

class myKMQuestionnaireRun extends KMQuestionnaireRun_Win32
{
    recId   myRecId;
}


formu çağırdığım tablonun recId'sini saklamak için bir parm metodu ekledim:

RecId  parmMyRecId(RecId _recId = myRecId)
{
    myRecId =_recId;
    return myRecId;
}


Daha sonra end metodunu türettim:

public void end(KMVirtualNetworkAnswerTableId _kmVirtualNetworkAnswerTableId)
{
    myCallerTable    tbl; //Questionnaries formunu çağıran tablo

    super(_kmVirtualNetworkAnswerTableId);
    if (_kmVirtualNetworkAnswerTableId == "")
        return;
  

      ttsBegin;
        update_recordSet tbl setting AnswerId = _kmVirtualNetworkAnswerTableId
            where tbl.RecId == myRecId;
        ttsCommit;
}

 
Ve kendi tablomdan formu bu kodla çağırdım:
...
myKMQuestionnaireRun       o = new myKMQuestionnaireRun();
myQTable            c;


    o.parmMyRecId(this.RecId);
    o.set(KMQuestionnaireRunMode::All,this.KMCollectionId, DirPersonUser::find(curUserId()).party());

    o.run();

...

9 Ağustos 2016 Salı

AXAPTA - Eldeki miktar (invent on hand)

//source: http://microsoft-dynamics-ax-erp.blogspot.com.tr/2012/07/find-inventonhand-in-axapta-x.html
static InventOnHand findOnHandByLocationId(ItemId _itemId, InventLocationId _inventLocationId = "")
{
    InventDim           inventDim;
    InventDimParm       inventDimParm;
    InventOnHand        inventOnHand = new InventOnHand();
    ;

    if (_inventLocationId == "")

         return InventOnhand::newItemId(_itemId);
    //Take a combination of dimension , against which you want to find the stock
    inventDim.InventLocationId  = _inventLocationId;

    //Set the flag for the selected dimensions as active
    inventDimParm.initFromInventDim(inventDim);

    //Initialize the inventSumDateDim with Date,item,dimension and dim parameter
    inventOnHand = InventOnHand::newParameters(_itemid,
                                               inventDim,
                                               inventDimParm);

    return inventOnHand;
}

24 Haziran 2016 Cuma

AXAPTA - Transfer emri bakiye kalan satırları temizlemek

Bir transfer emrinde bir satır tamamen bitirilmemişse ve bu satırda bitirilmeyen kısım bir çıkış emrinden rezerve ise İşlevler->Teslimat bakiyesi->Miktarı iptal et butonu işe yaramaz. Siparişte tipli yeterli satır olmadığını söyler ve hata verip çıkar. Bunun sebebi bu miktarın çıkış emrinden rezerve olmasıdır. Bu satırın rezervasyonu direk kodla kaldırılamaz (yani ben bir yolunu bulamadım) ve menüden kaldırılsa bile bağlantı halen duracağı için hatayı tekrar verir. Çıkış emrinde kalan miktarı sıfırlamanın bir yolunu bulamadım ve aşağıdaki yöntemi denedim, işe yarıyor:


    InventTransferTable header;
    InventTransferLine  line;
    WMSOrderTrans       orderTrans;
    InventTrans         inventTrans;
    ;
    while select header
            where header.TransferId == myTransferId
        join forupdate line
            where line.TransferId == header.TransferId &&
                  (line.QtyRemainReceive > 0 || line.QtyRemainShip>0)
    {
        ttsbegin;
        while select orderTrans
            where orderTrans.inventTransId == line.InventTransId &&
                  orderTrans.expeditionStatus != WMSExpeditionStatus::Complete &&
                  orderTrans.expeditionStatus != WMSExpeditionStatus::Cancelled &&
                  orderTrans.expeditionStatus != WMSExpeditionStatus::CancelledSW
        {
            WmsPickingLineCancel::newWMSPickingLineCancel(orderTrans).run();
        }
        while select forupdate inventTrans
            where (inventTrans.StatusIssue == StatusIssue::ReservPhysical ||
                   (inventTrans.TransChildRefId != "" &&
                    inventTrans.TransChildType == InventTransChildType::WMSOrder) ) &&
                  inventTrans.InventTransId == line.InventTransId
        {
            inventTrans.TransChildRefId = "";
            inventTrans.TransChildType = InventTransChildType::None;
            inventTrans.update();
            InventUpd_Reservation::newInventDim(InventMovement::construct(inventTrans,InventMovSubType::None),
                inventtrans.inventDim(),2,false).updateNow();
        }
        line.QtyRemainReceive = 0;
        line.QtyRemainShip    = 0;
        line.AutoReservation = NoYes::No;
        line.update();
        ttscommit;
    }

8 Haziran 2016 Çarşamba

AXAPTA - Bir malzeme çekme listesi veya satırını iptal

Tüm listenin iptali:
 
WMSPickingRouteCancel::newWMSPickingRoute(wMSPickingRoute).run(); 

Bir satırın iptali:


WMSPickingLineCancel::newWMSPickingLineCancel(wMSOrderTrans).run(); 

6 Mayıs 2016 Cuma

AXAPTA - Sign fonksiyonu düzgün çalışmıyor

AX 2009 ve 2012'deki sign fonksiyonu düzgün çalışmıyor. Negatif değerler için -1, sıfır için 0 ve pozitif değerler için +1 döndürmesi gerekirken negatif değerler için -1 ve diğer tüm değerler için +1 döndürüyor.

Global'deki Sign:

static real sign(real num)
{
    return num >= 0 ? 1 : -1;
}


Benim yaptığım düzeltme:

static int sign(real num)
{

   if (num < 0)
    return -1;
   else
    return num > 0 ? 1 : 0;
}

5 Mayıs 2016 Perşembe

AXAPTA - Malzeme çekme listesi oluşturmak

Bir forum sayfasından bulduğum çözümü kendim için class haline getirdim:

class KRC_WMSOrder
{
    WMSShipment         wmsShipment;
    SalesTable          salesTable;
    WMSPickingRoute     wmsPickingRoute;
    WMSPickingRouteLink wmsPickingRouteLink;
    salesLine           salesLine;
}


void createOrderLine(Qty _qty = salesLine.RemainSalesPhysical)
{

    InventMovement                  inventMovement;
    WMSOrder                        wmsOrder;
    WMSOrderCreate                  orderCreate;
    WMSOrderTrans                   wmsOrderTrans;
    ;
    inventMovement = InventMovement::construct(salesLine);
    orderCreate = WMSOrderCreate::newMovement(inventMovement,_qty);
    orderCreate.parmMustBeWMSOrderControlled(true);
    orderCreate.parmQty(_qty);
    orderCreate.parmMaxQty(_qty);
    orderCreate.run();
    wmsOrder = orderCreate.parmWMSOrder();
    wmsOrder.updateShipment(wmsShipment,_qty, wmsPickingRoute.PickingRouteID);
}


void createWmsPickingRoute()
{
    ;
    wmsPickingRoute.clear();
    wmsPickingRoute.initTypeOrderPick(wmsShipment, WMSExpeditionStatus::Activated,
        WMSPickRequestTable::construct(salesTable),"", true);
    wmsPickingRoute.ActivationDateTime = DateTimeUtil::utcNow();
    wmsPickingRoute.insert();
}


void createWmsPickingRouteLink()
{
    ;
    wmsPickingRouteLink.clear();
    wmsPickingRouteLink.initFromSalesTable(salesTable);
    wmsPickingRouteLink.initFromWMSPickingRoute(wmsPickingRoute);
    wmsPickingRouteLink.insert();
}


void createWmsShipment()
{
    ;
    wmsShipment.clear();
    wmsShipment.initTypeOrderPick();
    wmsShipment.insert();
}


SalesLine  parmSalesLine(SalesLine _salesLine = salesLine)
{
    ;
    salesLine = _salesLine;
    return salesLine;
}


SalesTable  parmSalesTable(SalesTable _salesTable = salesTable)
{
    ;
    salesTable = _salesTable;
    return salesTable;
}


void reserveItem(Qty _qty = salesLine.RemainSalesPhysical)
{
    InventUpd_Reservation   invUpdReservation;
    ;
    invUpdReservation = InventUpd_Reservation::newInventDim(InventMovement::construct(salesLine,InventMovSubType::None),
        salesLine.inventDim(),_qty,false);
    invUpdReservation.updateNow();
}


Örnek kullanım:

KRC_WMSOrder            kWMS = new krc_wmsorder();
kWMS.createWmsShipment();
;
ttsbegin;
kWMS.parmSalesTable(salesTable);
kWMS.createWmsPickingRoute();
kWMS.createWmsPickingRouteLink();
kWMS.parmSalesLine(salesLine);
kWMS.reserveItem();
kWMS.createOrderLine();

ttscommit;

AXAPTA - Formun args parametresi ile gelen kayda göre otomatik filtre yapmasını engellemek

Bu sorunun cevabını bir forum sayfasından buldum:


KRC_PlanWaves_DS.query().dataSourceNo(1).clearDynalinks();

24 Mart 2016 Perşembe

AXAPTA - Sysmailer ile mail gönderirken türkçe harf sorunu

SysMailer class ile mail gönderirken aşağıdaki kırmızı satırı eklemediğinizde türkçe harfler mailde çıkmayacaktır. Bu çözümü bir blog'dan bulmuştum ancak yerini şu an hatırlayamıyorum:


   SysEmailParameters  parameters;
    SysMailer           mailer;
    ;
    new InteropPermission(InteropKind::ComInterop).assert();
        parameters = SysEmailParameters::find();

        mailer = new SysMailer();
        if (parameters.SMTPRelayServerName)
        {
            mailer.SMTPRelayServer(parameters.SMTPRelayServerName,
                               parameters.SMTPPortNumber,
                               parameters.SMTPUserName,
                               SysEmailParameters::password(),
                               parameters.NTLM);
        }
        else
        {
            mailer.SMTPRelayServer(parameters.SMTPServerIPAddress,
                               parameters.SMTPPortNumber,
                               parameters.SMTPUserName,
                               SysEmailParameters::password(),
                               parameters.NTLM);
        }
        mailer.fromAddress(fromAddr);
        mailer.tos().appendAddress(toAddr);
        mailer.subject(subject);
        //türkçe harflerin düzgün gitmesi için:
        mailer.bodyCharSet("Windows-1254");
        if(FileName)
            mailer.attachments().add(FileName);
        mailer.ccs().appendAddress(ccAddr);
        mailer.bccs().appendAddress(bccAddr);
        mailer.htmlBody(body);
        mailer.sendMail();
    }
    CodeAccessPermission::revertAssert();

2 Mart 2016 Çarşamba

AXAPTA - Bir tablo alanının label değerini bulmak

Bir tablonun bir alanının label değerini bulmanın iki yolu var:

Eğer field label değerini direk extended data tipinden alıyorsa:


    if (curext()=="krc" && this.RBOInventItemGroupId == "")
        ret = checkfailed(strfmt("'%1' alanı doldurulmalıdır!..",
            new SysDictType(extendedTypeNum(RBORetailGroupId)).label()));

Eğer tabloda alana bir etiket yazıldıysa:

    if (curext()=="krc" && this.RBOInventItemGroupId == "")
        ret = checkfailed(strfmt("'%1' alanı doldurulmalıdır!..",
            new SysDictField(tablenum(WholeSalesCampaignGroup),
fieldnum(WholeSalesCampaignGroup,RBOInventItemGroupId)).label()));
 

5 Şubat 2016 Cuma

AXAPTA - Kullanıcının grid başlığından filtreyi değiştirmesini engelleme

SysQuery::findOrCreateRange(InventDim_DS.query().dataSourceTable(tablenum(InventDim)),fieldnum(InventDim,InventSiteId)).status(RangeStatus::Locked);

26 Ocak 2016 Salı

AX 2009 - Raporu PDF çıktı olarak arka planda çalıştırmak

Raporun Interactive property değerini No yapıyoruz. PrintMedium enum değerini değiştirerek html çıktı olarak çalışması da sağlanabilir.

     DocuType                docuType;
    TextIo                  textIo;
    FileIOPermission        fioPermission;
    #File
    ReportRun report;
    ;

    docuType = DocuType::find("Temp");
    fileName = strfmt(@"%1My Test Report.PDF",   docuType.ArchivePath);
   
    fioPermission = new FileIOPermission(fileName ,"RW");
    fioPermission.assert();

    if(Global::isRunningOnServer())
    {
        if(WinAPIServer::fileExists(fileName))
            WINAPIServer::deleteFile(fileName);
    }
    else
    {
        if(WinAPI::fileExists(fileName))
            WINAPI::deleteFile(fileName);
    }

    report = new ReportRun(new  Args(ReportStr(KRC_InventCoverReport)));
    report.printJobSettings().setTarget(PrintMedium::File);
    report.printJobSettings().preferredTarget(PrintMedium::File);
    report.printJobSettings().format(PrintFormat::PDF);
    report.printJobSettings().fileName(fileName);
    report.query().interactive(false);
    report.run();

22 Ocak 2016 Cuma

Axapta - Neden bazen MultiSelectionHelper bazen klasik okuma yöntemi?

Bir formda gridde seçili kayıtları okumak için klasik yöntem aşağıdaki gibidir:

 c = CustTable_DS.getFirst(true);
 while (c.RecId != 0)
 {
      info(c.Name);
      c = CustTable_DS.getNext();
 }


Ancak bu yöntemin bir sakıncası vardır. Bu yöntemle kayıt okuduğunuz zaman eğer ki kullanıcı listeden birkaç kayıt işaretlemeyip sadece üzerinde durduğu kaydı işlemek isterse o kayıt malesef atlanır. Bunu bertaraf etmek için aşağıdaki eklemeyi yapmak gerekir:


c = CustTable_DS.getFirst(true);
noSelected = true;
while (c.RecId != 0)
{
     noSelected = false;
     info(c.Name);
     c = CustTable_DS.getNext();

}
if  (noSelected)
    info(CustTable.Name);

MultiSelectionHelper sınıfı bu sıkıntıyı bertaraf eder:

 MultiSelectionHelper helper = MultiSelectionHelper::construct();
CustTable c;
;

helper.parmDatasource(CustTable_ds);

c = helper.getFirst();
while (c.RecId != 0)
{
      info(c.Name);
      c = helper.getNext();

}

Ancak MultiSelectionHelper sınıfının da bir dezavantajı vardır. Eğer ki kullanıcı gridde kayıtları sıralamak isterse ve o sıraya göre liste almak isterse yine yukarıdaki klasik yöntemi kullanmak gerekir zira MultiSelectionHelper sınıfı kullanıcının yaptığı sıralamayı malesef dikkate almaz.

19 Ocak 2016 Salı

Axapta - Query'ye boyut (dimension) bazında filtre eklemek

StrFmt ile boyut bazında filtre eklemek istediğimizde dimension alanın köşeli parantezleri dimension[2] = "0001" tarzı filtre eklemek istediğimizde hata veriyor. Doğru yöntemi bir forum sayfasında buldum:


QueryBuildDataSource    qbds = query.addDataSource(tablenum(EmplTable));
...
 qbds.addRange(fieldid2Ext(fieldnum(EmplTable, Dimension),1)).value("600742");